Object LibraryMessages
  with before [;
	  Answer, Ask, AskFor, Tell, Order, No, Yes, Sorry: "Maak, om met iemand te spreken, gebruik van het commando PRAAT MET <persoon>.";
 
          Examine:
	    if(lm_n == 1) "De duisternis van de wereld ken je al door introspectie.";
	  
	  Attack: 
	   if(noun == player) {
	     if(verhaaltracker.status < 7)
	       "Je wilt geen zelfmoord plegen.";
	     if(parent(final_scherf) == player)
	       <<AttackWith player final_scherf>>;
	       "Je hebt niets om jezelf mee te doden.";
	    }
	       
	   if(verhaaltracker.status < 6 && verhaaltracker.status > 1){
	     "Je kan je krachten beter sparen voor je confrontatie met de baron.";
	   }
	   else if (verhaaltracker.status == 1) {
	     "Het is de draak die je kapot moet maken.";
	   }
	   else 
	     "Je hebt al te veel kapot gemaakt.";
	            
	  Burn:
	      if(verhaaltracker.status < 5){
	          "Dingen in de fik steken zal je niet verder helpen.";
		} else {  
		  if(verhaaltracker.status < 7){
		    "Dat is niet brandbaar.";
		  } else {
		    "Je hebt niets waarmee je brand kan stichten - behalve misschien voor je eigen ziel in het hiernamaals.";
		  };
		};


	  Jump: 
	   if(verhaaltracker.status < 5 && verhaaltracker.status > 1){
	     "Je springt op en neer om je spieren los te maken. Je voelt je goed, een bonk kracht op zoek naar een mogelijkheid zich te uiten.";
	   }
	   else if (verhaaltracker.status == 1) {
	     "Het zware harnas belet je te springen.";
	   }
	   else 
	     "De zonden wegen te zwaar op je schouders.";
	     
	  Kiss:
	   if(verhaaltracker.status < 6 && verhaaltracker.status > 1){
	     "Vooralsnog zijn je gedachten vooral bij je dochter.";
	   }
	   else if (verhaaltracker.status == 1) {
	     "Daar is het niet het moment voor.";
	   }
	   else 
	     "Zoenen leidt tot zonde.";

	  Listen:
	   if(verhaaltracker.status < 7 && verhaaltracker.status > 1){
	     "Je hoort het bloed door je hoofd kloppen; verder hoor je niets bijzonders.";
	   }
	   else if (verhaaltracker.status == 1) {
	     "Je hoort het snuiven van de draak en het branden van een groot vuur.";
	   }
	   else 
	     "De stilte is pijnlijk.";
	     
	     
	Miscellany:
	   if(lm_n == 19) {
	     if(verhaaltracker.status == 1 && verhaaltracker.brand == 0) "Je ziet er heldhaftig uit in je zware harnas; bovendien ben je sterk, snel en voor de duivel niet bang. Als iemand de draak kan verslaan, ben jij het.";
	     
	     if(verhaaltracker.status == 1 && verhaaltracker.brand > 0) "Je bent een pilaar van vuur; aan alle kanten slaan de vlammen uit je vlees, alsof het vuur vanuit je binnenste zelf naar buiten barst.";
	     
	     if(verhaaltracker.status < 7 && kleding has worn) "In je ruige houthakkerskleding zie je er bijzonder mannelijk uit. Fikse spierbundels, een stoppelbaard en een stevige kaaklijn maken het plaatje compleet.";
	     
	     if(verhaaltracker.status < 7 && kleding hasnt worn && jas has worn) "Gehuld in je winterjas trotseer je de koude. Je stevige spieren en ongeschoren gezicht verlenen je een bijzonder masculien uiterlijk.";
             
             if(verhaaltracker.status < 7 && kleding hasnt worn && jas hasnt worn)
               "Slechts gekleed in je nachthemd trotseer je het duister en de koude. Je stevige spieren en ongeschoren gezicht verlenen je een bijzonder masculien uiterlijk.";
	       
	     if(verhaaltracker.status == 7)
	       "Daar sta je, naakt. Je bent de vader van Maartje. Je bent de baron. Ben je een schurk of een slachtoffer, een kwaadaardig monster of slechts een zwakkeling? Kan je nog veranderen? Kan je haar nog helpen?";
             };
	   if(lm_n == 9) "^Duisternis vult onmiddellijk de wereld.";
	   if(lm_n == 17) "In de duisternis kan je niets zien.";
	   if(lm_n == 30) "Zoiets zie je niet, of het is niet belangrijk om je ermee bezig te houden.";
	   if(lm_n == 5) "Wil je een HERSTART, een oud spel INLEZEN, het MENU (met informatie over hulpverlening, en over de gedachten achter ~De baron~) bekijken of een EINDE aan het verhaal maken?";
	     

	 Take:
	   if(lm_n == 2) 
	     if(verhaaltracker.status < 7 && verhaaltracker.status > 1) {
	       "Alleen de baron van M@:unchhausen kan iets bereiken door aan zichzelf te trekken, en dat is niet de baron waar jij naar op zoek bent.";
	     }
	     else {
	       "Je bent een baron, maar niet die van M@:unchhausen.";
	     };
	     
          Pray:
	     if(verhaaltracker.status < 7 && verhaaltracker.status > 1){
	       "~Maria, heilige moeder, sta mij bij op deze tocht,~ prevel je.";
	     }
	     else if (verhaaltracker.status == 1) {
	       "~Voor de glorie van God!~, roep je uit.";
	     }
               "BUG: this should not occur, as all PRAY-commands in scene 7 are trapped by the rooms. Please report this bug.";
	     
	  Pull:
	    if(lm_n == 4) "Dat zou geen zin hebben.";

          Sleep:          
	     if(verhaaltracker.status < 6 && verhaaltracker.status > 1){
	       "Het vooruitzicht van diepe, droomloze slaap lokt, maar je moet je dochter nog redden! Bovendien slaap je liever niet op de koude grond.";
	     }
	     else if (verhaaltracker.status == 1) {
	       "Je bent hier om de draak te verslaan, niet om een uiltje te knappen!";
	     }
	     else 
	       "Zo gemakkelijk kan je niet ontkomen. Dit is de tijd om te handelen.";
	  
	  
	  Sing:           
	     if(verhaaltracker.status < 6 && verhaaltracker.status > 1){
	       "~Don Giovanni!~ hoor je jezelf zingen met een diepe, onheilspellende basstem. Inderdaad voelt het alsof elk moment een goddelijke vergelding op aarde neer kan dalen om de wellustige schurk van dit stuk de afgrond van de Hel in te sleuren.";
	     }
	     else if (verhaaltracker.status == 1) {
	       "Je zingt een gewelddadig strijdlied, over een ridder die een kwaadaardige draak aan mootjes hangt.";
	     }
	     else 
	       "De noten stokken in je keel.";
	  
          Strong:         if(verhaaltracker.status < 7 && verhaaltracker.status > 1) {
	                     "Je vervloekt de kwaadaardige baron voor alles wat hij je heeft aangedaan.";
                           }
                          else "Je vloekt hartgrondig.";       
	  
	  Think:          "Beelden flitsen aan je geestesoog voorbij, maar je drukt ze weg. Je wilt niet denken.";

	  ThrowAt:
	    if(lm_n == 2) "Dat zou niets oplossen.";
	  
	  Touch:
	    if(lm_n == 1) "Ach nee, dat heeft geen zin.";
	  
          Wait:          	     
	     if(verhaaltracker.status < 6){
	       "Er is geen tijd te verliezen.";
	     }
	     else 
	       "Je treuzelt even - maar de nacht is te lang om op deze manier geheel voorbij te gaan.";
	   
	       
	  
	  Wake: "Zo gemakkelijk kan je aan deze duistere nachtmerrie niet ontkomen.";

          WaveHands:      
	     if(verhaaltracker.status < 6){
	       "Je zwaait je armen op en neer om je spieren los te maken. Je voelt je goed, een bonk kracht op zoek naar een mogelijkheid zich te uiten.";
	     }
	     else 
	       "Je armen hangen als lood langs je lichaam.";

   
        ];